﻿ Sample Problems > Usage > Variable_Types > complex_emw21

# complex_emw21

Navigation:  Sample Problems > Usage > Variable_Types >

# complex_emw21

{ COMPLEX_EMW21.PDE

This problem is an image of "Backstrom_Books|Waves|Electrodynamics|emw21.pde"

rewritten in terms of complex variables.

}

TITLE                           { emw21.pde }

'Plane Wave in a Conductor'

SELECT

errlim= 1e-3                 { Limit of relative error }

VARIABLES

Ez = complex(Ezr,Ezi)       { Real and imaginary parts }

DEFINITIONS                     { SI units throughout }

Lx= 1.0             Ly= 0.2 { Domain size }

eps0= 8.85e-12      eps     { Permittivity }

mu0= 4*pi*1e-7      mu       { Permeability }

sigma                       { Electric conductivity }

omega= 5e9                   { Angular frequency }

Ez_in= 1.0                   { Input field Ez }

Ep= magnitude(Ez)           { Modulus of Ez }

phase= carg(Ez)/pi*180       { Angle }

EQUATIONS

Ez:  del2( Ez)+ mu*omega*complex(eps*omega, -sigma)*Ez= 0

BOUNDARIES

region 'conductor'      eps= eps0       mu= mu0     sigma= 1e-1

start 'outer' (0,0)

natural(Ez)= complex(0,0)   line to (Lx,0)

value(Ez)= complex(0,0)     line to (Lx,Ly)     { Conducting }

natural(Ez)= complex(0,0)   line to (0,Ly)

value(Ez)= complex(Ez_in,0) line to close       { Input field }

PLOTS

elevation( Ez, Ep) from (0,Ly/2) to (Lx,Ly/2)

elevation( phase) from (0,Ly/2) to (Lx,Ly/2)

elevation( Ez, Ep) on 'outer'

contour( Ezr)     contour( Ezi)

END