Sample Problems > Usage > 3D_domains > 3d_spool

3d_spool

<< Click to Display Table of Contents >>

Navigation:  Sample Problems > Usage > 3D_domains >

3d_spool

Previous pageReturn to chapter overviewNext page

{ 3D_SPOOL.PDE

 

 This example shows the use of LIMITED REGIONS to construct a spool in a box in 3D.

 The core of the spool has a section of low conductivity at the center.

 The LAYER structure is as follows:

   Layers 1 and 7 are the sections of the box above and below the spool

   Layers 2 and 6 are the flanges of the spool and the box area surrounding the flanges.

   Layers 3 and 5 are the high-conductivity portions of the core and the surrounding box area.

   Layer 4 is the low-conductivity portion of the core and the surrounding box area.

 Click "Controls|Domain Review" or the "Domain Review" tool to watch the mesh construction.

}

title '3D LIMITED REGION EXAMPLE'

coordinates

   cartesian3

 

Variables

   U    

 

definitions

   K

   K1 = 1

   K2 = 10

   K3 = 0.01

   Lx = 1   Ly = 1 Lz = 1

  {extrusion values}

   t  = 0.25

   m = 0.05

   h = 0.25

   z0 = t/2

   z1 = t/2 + m

   z2 = t/2 + m + h

   z3 = t/2 + m + h + 2*m

   z4 = t/2 + m + h + 2*m + h

   z5 = t/2 + m + h + 2*m + h + m  

  {radii}

   rad = 0.5 - h/2

   rad1 = 0.5 - h/1

   

  {boundary values}

   U0 = 0

   U1 = 1

 

equations

   U:  DIV(K*GRAD(U)) = 0

 

extrusion

  surface "bottom of box" z=0

      layer "bottom gap"

  surface "spool bottom" z=z0

      layer "bottom flange"

  surface "top of bottom flange" z=z1

      layer "bottom core section"

  surface "bottom of core insert" z=z2

      layer "core insert"

  surface "top of core insert" z=z3

      layer "top core section"

  surface "bottom of top flange" z=z4

      layer "top flange"

  surface "top of spool" z=z5

      layer "top gap"

  surface "top of box" z=1

 

boundaries

  Surface 1 Value(U)=U0

  Surface 8 Value(U)=U1

 

  Region 1 "Box"

       K = K1

      start(0,0)

      line to (1,0) to (1,1) to (0,1) to close

 

  limited region 2 "Flanges"

      layer 2         K =K2

      layer 6         K =K2

 

      START (1/2,rad1)

      ARC(CENTER=1/2,1/2) ANGLE=360

      TO CLOSE

 

  limited Region 3   "Core"

      layer 3         K =K2

      layer 4         K =K3

      layer 5         K =K2

 

      START (1/2,rad)

      ARC(CENTER=1/2,1/2) ANGLE=360

      TO CLOSE

 

MONITORS

  plots

  grid(x,z) on y=0.5 paintregions

  contour(U) on y=0.5

  contour(U) on z=0.5

  contour(K) on x=0.5 painted

   

end