﻿ Sample Problems > Applications > Stress > bentbar

bentbar

Navigation:  Sample Problems > Applications > Stress >

bentbar

{ BENTBAR.PDE

This is a test problem from Timoshenko: Theory of Elasticity, pp41-46

A cantilever is loaded by a distributed shearing force on the free end,

while a point at the center of the mounted end is fixed.

The solution is compared to Timoshenko's analytic solution.

The equations of Stress/Strain arise from the balance of forces in a

material medium, expressed as

dx(Sx) + dy(Txy) + Fx = 0

dx(Txy) + dy(Sy) + Fy = 0

where Sx and Sy are the stresses in the x- and y- directions,

Txy is the shear stress, and

Fx and Fy are the body forces in the x- and y- directions.

The deformation of the material is described by the displacements,

U and V, from which the strains are defined as

ex = dx(U)

ey = dy(V)

gxy = dy(U) + dx(V).

The eight quantities U,V,ex,ey,gxy,Sx,Sy and Txy are related through the

constitutive relations of the material. In general,

Sx  =  C11*ex + C12*ey + C13*gxy - b*Temp

Sy  =  C12*ex + C22*ey + C23*gxy - b*Temp

Txy =  C13*ex + C23*ey + C33*gxy

In orthotropic solids, we may take C13 = C23 = 0.

In this problem we consider the thermal effects to be negligible.

}

title "Timoshenko's Bar with end load"

variables

U           { X-displacement }

V           { Y-displacement }

definitions

L = 1               { Bar length }

hL = L/2

W = 0.1             { Bar thickness }

hW = W/2

eps = 0.01*L

I = 2*hW^3/3       { Moment of inertia }

nu = 0.3           { Poisson's Ratio }

E  = 2.0e11         { Young's Modulus for Steel (N/M^2) }

{ plane stress coefficients }

G  = E/(1-nu^2)

C11 = G

C12 = G*nu

C22 = G

C33 = G*(1-nu)/2

amplitude=GLOBALMAX(abs(v)) { for grid-plot scaling }

mag=1/amplitude

force = -250         { total loading force in Newtons (~10 pound force) }

dist = 0.5*force*(hW^2-y^2)/I       { Distributed load }

Sx = (C11*dx(U) + C12*dy(V))       { Stresses }

Sy = (C12*dx(U) + C22*dy(V))

Txy = C33*(dy(U) + dx(V))

{ Timoshenko's analytic solution:  }

Vexact = (force/(6*E*I))*((L-x)^2*(2*L+x) + 3*nu*x*y^2)

Uexact = (force/(6*E*I))*(3*y*(L^2-x^2) +(2+nu)*y^3 -6*(1+nu)*hW^2*y)

Sxexact = -force*x*y/I

Txyexact = -0.5*force*(hW^2-y^2)/I

initial values

U = 0

V = 0

equations             { the displacement equations }

U:  dx(Sx) + dy(Txy) = 0

V:  dx(Txy) + dy(Sy) = 0

boundaries

region 1

start (0,-hW)

load(U)=0         { free boundary on bottom, no normal stress }

line to (L,-hW)

value(U) = Uexact { clamp the right end }

mesh_spacing=hW/10

line to (L,0) point value(V) = 0

line to (L,hW)

load(U)=0         { free boundary on top, no normal stress }

mesh_spacing=10

line to (0,hW)

line to close

plots

grid(x+mag*U,y+mag*V)   as "deformation"   { show final deformed grid }

elevation(V,Vexact) from(0,0) to (L,0) as "Center Y-Displacement(M)"

elevation(V,Vexact) from(0,hW) to (L,hW) as "Top Y-Displacement(M)"

elevation(U,Uexact) from(0,hW) to (L,hW) as "Top X-Displacement(M)"

elevation(Sx,Sxexact) from(0,hW) to (L,hW) as "Top X-Stress"

elevation(Txy,Txyexact) from(0,0) to (L,0) as "Center Shear Stress"

end