2d_finite_potential_well

<< Click to Display Table of Contents >>

Navigation:  Sample Problems > Applications > Quantun_Mechanics >

2d_finite_potential_well

Previous pageReturn to chapter overviewNext page

{ 2D_FINITE_POTENTIAL_WELL.PDE

 Submitted by Ali Reza Ghaffari, 07/22/2016.

 

 This script solves the Schrodinger equation for a two dimensional finite potential well.

 This script finds energies and wave functions of a wire with rectangle cross section.

 The wire is made up of GA As which is placed in a AlGalAs medum.

}

TITLE 'infinitely deep rectangular wires'

 

COORDINATES cartesian2

 

VARIABLES Phi     {the wavefunction}

 

SELECT

   modes=4

   NGRID=13

   ERRLIM=1e-3

   painted             { show colour-filled contours }

   thermal_colors = on { red is minimum }

 

DEFINITIONS

   mass{default value}

   volt { in eV}

   hbar=1.05457e-34

   m0=9.11e-31

   e0=1.6e-19

   xx=200e-10

   yy=200e-10

   x1=50e-10

   y1=50e-10

   x2=150e-10

   y2=150e-10

   v0=.228

   mass_shell=0.067*m0 {mhh}!0.067 {GaAs}

   mass_core=0.1*m0!  {Al0.5Ga0.5As}

   N=integral(phi^2)

 

EQUATIONS

   Phi: ((-1)* hbar^2/(2*mass*e0))*div(grad(Phi))+volt*Phi-LAMBDA*Phi =0

 

BOUNDARIES

Region 1

   mass= mass_shell, volt=v0

  start(0,0)

  point value (phi)=0 line to (xx,0)

  value (phi)=0 line to (xx,yy)

  value (phi)=0 line to (0,yy)

  to close

 

Region 2

   mass= mass_core, volt=0

  start(x1,y1)

  line to (x2,y1) to (x2,y2) to (x1,y2)

  to close

 

!MONITORS

! no monitors since problem solves so fast

 

PLOTS

CONTOUR(Phi^2/sqrt(N))

 

SUMMARY

REPORT(LAMBDA*1000) as "Energy Level (meV)" !in milielectron volt

 

END