<< Click to Display Table of Contents >> Navigation:  Sample Problems > Usage > 1D > 1d_cylinder_transient

{ 1D_CYLINDER_TRANSIENT.PDE

 

 This problem analyzes the diffusive loss of a solute from a solvent due to leakage

 across an outer boundary using 1D cylindrical coordinates.

 

}  

 

title '1D time dependent diffusion in a Cylinder'  

 

coordinates  

   cylinder1("R")  

 

variables  

   C  

 

definitions  

   D = 1  

   source = 0  

   b = 1  

   a = 2  

   C0 = 10  

   diss = 0.01     ! dissolution coefficient

   Cext = 0       ! external sink concentration

   Flux = -D*dr(C)  

 

initial values  

   C = C0  

   

equations  

   C: div(D*grad(C)) + source = dt(C)  

 

boundaries  

  region 1  

      start (b)   point load(C)=0  

      line to (a) point load(C)=diss*(Cext-C) !outer leakage rate

 

time 0 to 10  

 

monitors  

  for cycle=1  

      elevation(C) from (b) to (a)  

 

plots  

  for cycle=10  

      elevation(C) from (b) to (a)  

      elevation(Flux) from (b) to (a) range=(0,0.01) {minimum plot range}  

  history(C) at (b) ((b+a)/2) (a)  

  history(Flux) at (b) ((b+a)/2) (a)  

 

end