Example : Stress Analysis Script

{ view comments }

TITLE 'Plane Stress tension strip with a hole'

SELECT

errlim = 1e-4       { increase accuracy to resolve stresses }

VARIABLES

U                       { declare U and V to be the system variables }
V

DEFINITIONS

nu = 0.3                       { define Poisson's Ratio }
E = 21                          { Young's Modulus x 1e-11 }
G = E/(1-nu^2)
C11 = G
C12 = G*nu
C22 = G
C33 = G*(1-nu)/2
p1 = (1-nu)/2   { = C33/G }

EQUATIONS   { define the Plane-Stress displacement equations }

U:      dx(dx(U) + nu*dy(V)) + p1*dy(dy(U) + dx(V)) = 0
V:      dy(dy(V) + nu*dx(U)) + p1*dx(dy(U) + dx(V)) = 0

BOUNDARIES

REGION 1

start (0,0)
load(U)=0     load(V)=0             { free boundary, no normal stress }
line to (3,0)                                  { walk bottom }

load(U)=0.1  load(V) = 0            { define an X-stress of 0.1 unit on right edge}
line to (3,1)

load(U)=0  load(V)=0                 { free boundary top }
line to (0,1)

value(U)=0   value(V)=0              { fixed displacement on left edge }
line to close

{ Cut out a hole: }
start(1,0.25)
load(U) = 0   load(V) = 0
arc(center=1,0.5) angle=-360 to close

MONITORS

grid(x+U,y+V) { show deformed grid as solution progresses }

PLOTS { hardcopy at finish: }

grid(x+U,y+V) { show final deformed grid }
vector(U,V) as "Displacement" { show displacement field }
contour(U) as "X-Displacement"
contour(V) as "Y-Displacement"
contour((C11*dx(U) + C12*dy(V))) as "X-Stress"
contour((C12*dx(U) + C22*dy(V))) as "Y-Stress"
surface((C11*dx(U) + C12*dy(V))) as "X-Stress"
surface((C12*dx(U) + C22*dy(V))) as "Y-Stress"

END