User Guide > Using FlexPDE in One-Dimensional Problems

FlexPDE treats problems in one space dimension as a degenerate case of two dimensional problems.

The construction of a problem descriptor follows the principles laid out in previous sections, with the following specializations:

•The COORDINATES specification must be CARTESIAN1, CYLINDER1 or SPHERE1

•Coordinate positions are given by one dimensional points, as in

START(0) LINE TO (5)

•The boundary path is in fact the domain, so the boundary must not CLOSE on itself.

•Since the boundary path is the domain, boundary conditions are not specified along the path. Instead we use the existing syntax of POINT VALUE and POINT LOAD to specify boundary conditions at the end points of the domain:

START(0) POINT VALUE(u)=0 LINE TO (5) POINT LOAD(u)=1

•Only ELEVATION and HISTORY are meaningful plots in one dimension.

Our basic example problem does not have a one-dimensional analog, but we can adapt it to an insulating spherical shell between two spherical reservoirs as follows:

TITLE 'Heat flow through an Insulating shell'

COORDINATES

Sphere1

VARIABLES

Phi { the temperature }

DEFINITIONS

K = 1 { default conductivity }

R1 = 1 { the inner reservoir }

Ra = 2 { the insulator inner radius }

Rb = 3 { the insulator outer radius }

R2 = 4 { the outer reservoir }

EQUATIONS

Div(-k*grad(phi)) = 0

BOUNDARIES

REGION 1 { the total domain }

START(R1) POINT VALUE(Phi)=0

LINE TO (R2) POINT VALUE(Phi)=1

{ note: no 'Close'! }

REGION 2 'blob' { the embedded layer }

k = 0.001

START (Ra) LINE TO (Rb)

PLOTS

ELEVATION(Phi) FROM (R1) to (R2)

END