Sample Problems > Usage > Periodicity

{ PERIODIC+TIME.PDE

This example is a time-dependent version of PERIODIC.PDE

}

title 'Time-dependent Periodic Boundary Test'

variables

u(0.01)

definitions

k = 0.1

h=0

x0=0.5 y0=-0.2

x1=1.1 y1=0.2

equations

u : div(K*grad(u)) + h = dt(u)

boundaries

region 1

start(-1,-1)

value(u)=0 line to (0.9,-1) to (1,-1)

{ The following arc is required to be a periodic image of an arc

two units to its left. (This image boundary has not yet been defined.) }

periodic(x-2,y) arc(center=-1,0) to (1,1)

value(u)=0 line to (-1,1)

{ The following arc provides the required image boundary for the previous

periodic statement }

nobc(u) { turn off the value BC }

arc(center= -3,0) to close

{ an off-center heat source provides the asymmetric conditions to

demonstrate the periodicity of the solution }

region 2 h=10 k=10

start(x0,y0) line to (x1,y0) to (x1,y1) to (x0,y1) to close

time 0 to 10

monitors

for cycle=1

grid(x,y)

contour(u)

plots

for cycle=10

grid(x,y)

contour(u)

end

periodic+time