<< Click to Display Table of Contents >> Navigation:  Sample Problems > Usage > Misc > two_histories

{ TWO_HISTORIES.PDE  

 

 This example illustrates use of multiple arguments in a HISTORY plot.

 It also shows the use of the WINDOW plot qualifier on a HISTORY plot.

 The problem is the same as FLOAT_ZONE.PDE.

}  

 

title  

"Multiple HISTORY functions"  

 

coordinates  

 xcylinder('Z','R')  

 

select  

 cubic                         { Use Cubic Basis }  

 

variables  

 temp (threshold=100)  

 

definitions  

 k = 0.85                           {thermal conductivity}  

 cp = 1                             { heat capacity }  

 long = 18  

 H = 0.4                             {free convection boundary coupling}  

 Ta = 25                             {ambient temperature}  

 A = 4500                           {amplitude}  

 

 source = A*exp(-((z-1*t)/.5)^2)*(200/(t+199))  

 

initial value  

 temp = Ta  

 

equations  

 temp:  div(k*grad(temp)) + source = cp*dt(temp)  

 

boundaries  

region 1  

  start(0,0)  

  natural(temp) = 0 line to (long,0)  

  value(temp) = Ta line to (long,1)  

  natural(temp) = -H*(temp - Ta) line to (0,1)  

  value(temp) = Ta line to close  

feature  

  start(0.01*long,0) line to (0.01*long,1)  

 

time -0.5 to 19 by 0.01  

 

monitors  

for t = -0.5 by 0.5 to (long + 1)  

elevation(temp) from (0,1) to (long,1) range=(0,1800) as "Surface Temp"  

contour(temp)  

 

plots  

for t = -0.5 by 0.5 to (long + 1)  

elevation(temp) from (0,0) to (long,0) range=(0,1800) as "Axis Temp"  

 

histories  

 

history(temp,dt(temp)) at (5,0) (10,0) (15,0)  

history(temp,dt(temp)) at (5,0) (10,0) (15,0) window = 5 ! moving window

history(temp,dt(temp)) at (5,0) (10,0) (15,0) window(3,8) ! fixed window

history(integral(temp),integral(dt(temp)))  

 

end