﻿ Sample Problems > Usage > Import_Export > mesh_import

mesh_import

Navigation:  Sample Problems > Usage > Import_Export >

mesh_import   { MESH_IMPORT.PDE

This problem demonstrates the use of the TRANSFERMESH facility to import

both data and mesh structure from MESH_EXPORT.PDE.

MESH_EXPORT.PDE must be run before running this problem.

}

title 'Testing the TRANSFERMESH statement'

select

painted             { paint all contour plots }

variables

U

V

definitions

nu = 0.3           { define Poisson's Ratio }

E  = 21             { Young's Modulus x 10^-11 }

G  = E/(1-nu^2)

C11 = G

C12 = G*nu

C22 = G

C33 = G*(1-nu)/2

alpha = 1e-3

b = G*alpha*(1+nu)

{ HERE IS THE TRANSFERMESH INPUT FUNCTION: }

transfermesh('mesh_export_output/transferm.xfr',Temp)

Sxx = C11*dx(U) + C12*dy(V) - b*Temp

Syy = C12*dx(U) + C22*dy(V) - b*temp

Sxy = C33*(dy(U) + dx(V))

initial values

U = 0

V = 0

equations

U:  dx(Sxx) + dy(Sxy)  = 0

V:  dy(Syy) + dx(Sxy) = 0

boundaries

Region 1

start "OUTER" (0,0)

natural(U)=0 value(V)=0         { no y-motion on x-axis }

line to(1,0)

natural(U)=0 natural(V)=0       { free outer boundary }

arc (center=0,0) to (0,1)

value(U)=0 natural(V)=0         { no x-motion on y-axis }

line to close

natural(U)=0 natural(V)=0       { free inner boundary }

start "INNER" (0.4,0.2)

arc (center=0.4,0.4)

to (0.6,0.4)

to (0.4,0.6)

to (0.2,0.4)

to close

monitors

grid(x+100*U,y+100*V)

plots

contour(Temp)

grid(x+100*U,y+100*V)

vector(U,V) as "Displacement"

contour(U) as "X-Displacement"

contour(V) as "Y-Displacement"

contour(Sxx) as "X-Stress"

contour(Syy) as "Y-Stress"

surface(Sxx) as "X-Stress"

surface(Syy) as "Y-Stress"

end