|
<< Click to Display Table of Contents >> 3d_contact_region |
  
|
|
<< Click to Display Table of Contents >> 3d_contact_region |
|
{ 3D_CONTACT_REGION.PDE
This problem shows the use of a contact resistance boundary between layers.
The resistance model is applied only to one region of the boundary surface.
(This is a modification of problem 3D_CONTACT.PDE).
}
title 'steady-state 3D heat conduction with Contact Resistance'
select
regrid=off { use fixed grid }
coordinates
cartesian3
variables
Tp
definitions
long = 1
wide = 1
K { thermal conductivity -- values supplied later }
Q = 10*exp(-x^2-y^2-z^2) { Thermal source }
initial values
Tp = 0.
equations
Tp : div(k*grad(Tp)) + Q = 0 { the heat equation }
extrusion z = -long,0,long { divide Z into two layers }
boundaries
surface 1 value(Tp)=0 { fix bottom surface temp }
surface 3 value(Tp)=0 { fix top surface temp }
Region 1 { define full domain boundary in base plane }
layer 1 k=1 { bottom right brick }
layer 2 k=0.1 { top right brick }
start(-wide,-wide)
value(Tp) = 0 { fix all side temps }
line to (wide,-wide) { walk outer boundary in base plane }
to (wide,wide)
to (-wide,wide)
to close
Region 2 { overlay a second region in left half }
{ CONTACT RESISTANCE IN REGION 2 ONLY: }
surface 2 contact(tp)=jump(tp)/10
layer 1 k=0.2 { bottom left brick }
layer 2 k=0.4 { top left brick }
start(-wide,-wide)
line to (0,-wide) { walk left half boundary in base plane }
to (0,wide)
to (-wide,wide)
to close
monitors
contour(Tp) on z=0.01 as "XY Temp - Upper"
contour(Tp) on z=-0.01 as "XY Temp - Lower"
contour(Tp) on x=0 as "YZ Temp"
contour(Tp) on y=0 as "ZX Temp"
elevation(Tp) from (-wide/2,0,-long) to (wide/2,0,long) as "Left Side Temp"
plots
contour(Tp) on z=0.01 as "XY Temp - Upper"
contour(Tp) on z=-0.01 as "XY Temp - Lower"
contour(Tp) on x=0 as "YZ Temp"
contour(Tp) on y=0 as "ZX Temp"
elevation(Tp) from (-wide/2,0,-long) to (-wide/2,0,long) as "Left Side Temp"
surface(Tp) on y=0 as "ZX Temp" Viewpoint(-3.5,8.2,31)
end