Sample Problems > Usage > Misc > rotated

{ ROTATED_ELLIPSE.PDE

This example shows the use of ROTATE to create a rotated

ellipse. The selector MERGEDIST is used to allow fewer digits

of accuracy in the positions of the points on the ellipse.

}

TITLE 'Electrostatic Potential and Electric Field'

VARIABLES V Q

SELECT mergedist = 0.01 ! merge imprecise points in ellipse

DEFINITIONS eps = 1

EQUATIONS

V: div(eps*grad(V)) = 0 {potential equation}

Q: div(grad(Q)/eps) = 0 {adjoint equation}

BOUNDARIES

REGION 1

start(0,0)

value(V) = 0 natural(Q) = tangential(grad(V))

line to (3,0)

natural(V)=0

line to (3, 2.5)

value(V) = 100 natural(Q) = tangential(grad(V))

arc(center = 1.5, 2.5) angle= 180.

natural(V)=0

line to close

! embedded path will become an EXCLUDE :

start( 2.08, 2.08)

natural(V) = 0 natural(Q) = tangential(grad(V))

arc(center = 1.5, 1.5 rotate= 45.) to ( 1.22, 1.78)

arc(center = 1.5, 1.5 rotate= 45.) to ( 0.92, 0.92)

arc(center = 1.5, 1.5 rotate= 45.) to ( 1.78, 1.22)

arc(center = 1.5, 1.5 rotate= 45.) to ( 2.08, 2.08)

PLOTS

grid(x,y)

contour(V) as 'Potential'

surface(V) as 'Potential'

contour(Q) as 'Field Lines'

vector(-dx(V),-dy(V)) as 'Electric Field'

END

rotated_ellipse