morse_potential

<< Click to Display Table of Contents >>

Navigation:  Sample Problems > Applications > Quantun_Mechanics >

morse_potential

Previous pageReturn to chapter overviewNext page

{ MORSE_POTENTIAL.PDE

 Submitted by Ali Reza Ghaffari, 07/21/2016.

 

 This is a Quantum Mechanic example that shows the power of Flexpde to solve such examples.

 We want to solve the Schrodinger equation for Morse Potential V(x)=V0(1-exp(-alpha*x))^2 and

 find the Eigen values and functions. The exact energies can be extracted from the formula below.

 

 E[n] := h*2^(1/2)*(V0*alpha^2/m0)^(1/2)*(n+1/2)-1/2*alpha^2*h^2/m0*(n+1/2)^2

 

 For n=0 to 4 :

     E[0] := 3.037277660

     E[1] := 8.361832980

     E[2] := 12.68638830

     E[3] := 16.01094362

     E[4] := 18.33549894

 

 You can compare the results of this script with above energies.

}

 

TITLE 'Morse Potential'

 

COORDINATES CARTESIAN1

 

VARIABLES Phi

 

SELECT

   modes=6

   NGRID=30

   ERRLIM=1e-3

 

DEFINITIONS

   volt

   hbar=1

   m0=1

   v0=20

   a=10 ! the renge of integrals

   alpha=1

   volt=v0*(1-exp(-alpha*x))^2

   N=integral(phi^2)

 

EQUATIONS

   Phi : (-hbar^2/2/m0)*(dx(dx(Phi)))+volt*Phi-LAMBDA*Phi=0

 

BOUNDARIES

REGION 1

  START (-3*a) point value(phi)=0

  LINE TO (3*a) point value(phi)=0

 

!MONITORS

! no monitors since problem solves so fast

 

PLOTS

ELEVATION(Phi+lambda,volt) FROM (-1) to (6) zoom (-1,0,6,10)

 

SUMMARY

REPORT(LAMBDA)

 

END