|
<< Click to Display Table of Contents >> capacitance |
  
|
|
<< Click to Display Table of Contents >> capacitance |
|
{ CAPACITANCE.PDE
See discussion in Help section "Electromagnetic Applications | Electrostatics".
}
TITLE 'Capacitance per Unit Length of 2D Geometry'
{ 17 Nov 2000 by John Trenholme }
SELECT
errlim 1e-4
thermal_colors on
plotintegrate off
VARIABLES
v
DEFINITIONS
mm = 0.001 ! meters per millimeter
Lx = 300 * mm ! enclosing box dimensions
Ly = 150 * mm
b = 0.7 ! radius of conductor / radius of entire cable
x0 = 0.25 * Lx ! position and size of cable raised to fixed potential
y0 = 0.5 * Ly
r0 = 15 * mm
x1 = 0.9 * Lx
y1 = 0.3 * Ly
r1 = r0
epsr ! relative permittivity of any particular region
epsd = 3 ! relative permittivity of cable dielectric
eps0 = 8.854e-12 ! permittivity of free space
eps = epsr * eps0
v0 = 1 ! fixed potential of the cable
energyDensity = dot( eps * grad( v), grad( v))/2 ! field energy density
EQUATIONS
div( eps * grad( v)) = 0
BOUNDARIES
region 1 'inside' epsr = 1
start 'outer' ( 0, 0) value( v) = 0
line to ( Lx, 0) line to ( Lx, Ly) line to ( 0, Ly) line to close
region 2 'diel0' epsr = epsd
start 'dieb0' ( x0 + r0, y0)
arc ( center = x0, y0) angle = 360
region 3 'cond0' epsr = 1
start 'conb0' ( x0 + b * r0, y0) value( v) = v0
arc ( center = x0, y0) angle = 360
region 4 'diel1' epsr = epsd
start 'dieb1' ( x1 + r1, y1)
arc ( center = x1, y1) angle = 360
region 5 'cond1' epsr = 1000 ! fake metallic conductor
start 'conb1' ( x1 + b * r1, y1)
arc ( center = x1, y1) angle = 360
PLOTS
grid(x,y) zoom(x0-1.1*r0, y0-1.1*r0, 2.2*r0) ! 3-term zoom generates a square window }
contour( v) as 'Potential'
contour( v) as 'Potential Near Driven Conductor'
zoom(x0-1.1*r0, y0-1.1*r0, 2.2*r0)
contour( v) as 'Potential Near Floating Conductor'
zoom(x1-1.1*r1, y1-1.1*r1, 2.2*r1)
elevation( v) as 'Potential from Wall to Driven Conductor' from ( 0,y0) to ( x0, y0)
elevation( v) as 'Potential from Driven to Floating Conductor' from ( x0, y0) to ( x1, y1)
vector( grad( v)) as 'Field'
contour( energyDensity) as 'Field Energy Density' png(3072,2)
contour( energyDensity) as 'Field Energy Density Near Floating Conductor'
zoom(x1-1.2*r1, y1-1.2*r1, 2.4*r1)
elevation( energyDensity) from ( x1 - 2 * r1, y1) to ( x1 + 2 * r1, y1)
as 'Field Energy Density Near Floating Conductor'
contour( epsr) paint on "inside" as 'Definition of Inside'
SUMMARY png(3072,2)
report sintegral( normal( eps * grad( v)), 'conb0', 'diel0') as 'Driven charge'
report sintegral( normal( eps * grad( v)), 'outer', 'inside') as 'Outer charge'
report sintegral( normal( eps * grad( v)), 'conb1', 'diel1') as 'Floating charge'
report sintegral( normal( eps * grad( v)), 'conb0', 'diel0') / v0 as 'Capacitance (f/m)'
report integral( energyDensity, 'inside') as 'Energy (J/m)'
report 2 * integral( energyDensity, 'inside') / v0^2 as 'Capacitance (f/m)'
report 2 * integral( energyDensity, 'inside') / ( v0 * sintegral( normal( eps * grad( v)), 'conb0', 'diel0'))
as 'cap_by_energy / cap_by_charge'
END