|
<< Click to Display Table of Contents >> 3d_vector_magnetron |
  
|
|
<< Click to Display Table of Contents >> 3d_vector_magnetron |
|
{ 3D_VECTOR_MAGNETRON
MODEL OF A GENERIC MAGNETRON IN 3D USING VECTOR VARIABLES
This is a modification of 3D_MAGNETRON.PDE.
The development of this model is described in the Magnetostatics chapter of the
Electromagnetic Applications section.
}
TITLE 'Oval Magnet'
COORDINATES
CARTESIAN3
SELECT
ngrid=25
alias(x) = "X(cm)"
alias(y) = "Y(cm)"
alias(z) = "Z(cm)"
VARIABLES
A = vector (Ax,Ay) { assume Az is zero! }
DEFINITIONS
MuMag=1.0 ! Permeabilities:
MuAir=1.0
MuSST=1000
MuTarget=1.0
Mu=MuAir ! default to Air
MzMag = 10000 ! permanent magnet strength
Mx=0 My=0 Mz=0
M = vector(Mx,My,Mz) ! global magnetization variable
N = tensor((0,Mz,0),(-Mz,0,0),(0,0,0))
B = curl(Ax,Ay,0) ! magnetic induction vector
Bxx= xcomp(B)
Byy= ycomp(B) ! unfortunately, "By" is a reserved word.
Bzz= zcomp(B)
EQUATIONS
A: div((grad(A)+N)/mu) = 0
EXTRUSION
SURFACE "Boundary Bottom" Z=-5
SURFACE "Magnet Plate Bottom" Z=0
LAYER "Magnet Plate"
SURFACE "Magnet Plate Top" Z=1
LAYER "Magnet"
SURFACE "Magnet Top" Z=2
SURFACE "Boundary Top" Z=8
BOUNDARIES
Surface "boundary bottom" value (Ax)=0 value(Ay)=0
Surface "boundary top" value (Ax)=0 value(Ay)=0
REGION 1 {Air bounded by conductive box }
START (20,-10)
value(A)=vector(0,0,0)
ARC(center=20,0) angle=180
LINE TO (-20,10)
ARC(center=-20,0) angle=180
LINE TO CLOSE
LIMITED REGION 2 { Magnet Plate }
LAYER "Magnet Plate" Mu=MuSST
LAYER "Magnet" Mu=MuMag Mz = MzMag
START (20,-8)
ARC(center=20,0) angle=180
LINE TO (-20,8)
ARC(center=-20,0) angle=180
LINE TO CLOSE
LIMITED REGION 3 { Inner Gap }
LAYER "Magnet"
START (20,-6)
ARC(center=20,0) angle=180
LINE TO (-20,6)
ARC(center=-20,0) angle=180
LINE TO CLOSE
LIMITED REGION 4 {Inner Magnet }
LAYER "Magnet" Mu=MuMag Mz = -MzMag
START (20,-2)
ARC(center=20,0) angle=180
LINE TO (-20,2)
ARC(center=-20,0) angle=180
LINE TO CLOSE
MONITORS
grid(y,z) on x=0
grid(x,z) on y=0
grid(x,y) on z=1.01
contour(Ax) on x=0
contour(Ay) on y=0
PLOTS
grid(y,z) on x=0
grid(x,z) on y=0
grid(x,y) on z=1.01
contour(Ax) on x=0
contour(Ay) on y=0
vector(Bxx,Byy) on z=2.01 norm
vector(Byy,Bzz) on x=0 norm
vector(Bxx,Bzz) on y=4 norm
contour(magnitude(Bxx,Byy,Bzz)) on z=2
END