<< Click to Display Table of Contents >> Navigation:  Sample Problems > Applications > Heatflow > 1d_float_zone

{  1D_FLOAT_ZONE.PDE  

 

  This is a version of the example FLOAT_ZONE.PDE in 1D cartesian geometry.

 

}  

 

title  

"Float Zone in 1D Cartesian geometry"  

 

select  

 cell_limit=100  

 

coordinates  

 cartesian1  

 

variables  

 temp(threshold=100)  

 

definitions  

 k = 10   {thermal conductivity}  

 cp = 1   { heat capacity }  

 long = 18  

 H = 0.4   {free convection boundary coupling}  

 Ta = 25   {ambient temperature}  

 A = 4500 {amplitude}  

 

 source = A*exp(-((x-1*t)/.5)^2)*(200/(t+199))  

 

initial value  

 temp = Ta  

 

equations  

 temp : div(k*grad(temp)) + source -H*(temp - Ta) = cp*dt(temp)  

 

boundaries  

region 1  

  start(0) point value(temp) = Ta  

  line to (long) point value(temp) = Ta  

 

time -0.5 to 19 by 0.01  

 

monitors  

for t = -0.5 by 0.5 to (long + 1)  

  elevation(temp) from (0) to (long) range=(0,1800) as "Surface Temp"  

 

plots  

for t = -0.5 by 0.5 to (long + 1)  

  elevation(temp) from (0) to (long) range=(0,1800) as "Axis Temp"  

  elevation(source) from(0) to (long)  

  elevation(-k*grad(temp)) from(0) to (long)  

 

histories  

history(temp) at (0) (1) (2) (3) (4) (5) (6) (7) (8) (9)  

                  (10) (11) (12) (13) (14) (15) (16) (17) (18)  

 

end